数据库邮件（Database Mail）是SQL Server 2005数据库引擎中新增的一项简单实用的功能。Database Mail代替了SQL Mail，它使用一个简单邮件传输协议（SMTP）服务器，而不是SQL Mail所要求的MAPI账号来发送电子邮件。

这允许你的组织发送带附件和查询结果的电子邮件，附加查询结果，以及格式化HTML电子邮件。你还可以用它设定许多其它配置，而不需要你拥有一台Exchange服务器或配置任何类型的MAPI工作区。

使用Database Mail的好处

除完全以SMTP为基础外，Database Mail还具有许多其它优点：

• 它在数据库引擎以外运行，因此对数据库引擎的压力最小。
• 它支持群集，完全支持群集环境。
• 它的用户资料（Profile）允许使用冗余SMTP服务器。（我将在本文后部分详细讨论这一点。）
• 它允许你以参数的形式向存储过程发送查询文本，存储过程将执行查询并在电子邮件中发送结果。
• 消息通过一个Service Broker队列异步传送，因此你在发送电子邮件时不必等待回应。
• 它为电子邮件发送提供多重安全保护，如一个控制附件扩展名的过滤器和一个附件大小管理器。

建立和使用Database Mail

在建立一个Database Mail解决方案前，你需要进行一些规划工作。首先，你必须具有一台有效的SMTP服务器来传送电子邮件。如果你没有SMTP服务器，请参阅微软知识库文章308161了解建立SMTP服务器的相关信息。如果你无法确定组织是否拥有SMTP服务器，询问你的网络管理员获得机器名称或服务器的IP地址。你的网络管理员可能需要对服务器进行配置，以便SQL Server能够发送电子邮件。

在Database Mail中，账户（Account）保存数据库引擎用来发送电子邮件消息的信息。一个账户只为一台电子邮件服务器保存信息，如账户名、电子邮件地址、回复电子邮件地址、服务器名称或IP地址，以及一些可选的安全设置。

要发送一封Database Mail电子邮件，必须使用一个用户资料（Profile）。用户资料为一个或几个账户设立。这种用户资料-账户设置非常有用。它允许你将几个账户和一个用户资料联系起来，这意味着你可以将几台电子邮件服务器和一个用户资料联系起来。

因此，当你试图发送一封电子邮件时，系统会尝试用户资料中的每个账户，直到消息被成功发送出去。如果一台或几台SMTP服务器出现故障，这种设置就十分有用。它还允许你开发发送电子邮件的应用程序代码，而不必担心针对不同的环境修改Profile名称。你可以在开发和生产环境中使用相同的Profile名称，唯一的差别在于用户资料中包含的账户有所不同。

该是时候了解如何建立一个Database Mail账户了。在我们的例子中，我假设你正坐在一台你具有系统管理员访问权限的开发机器前。如果你没有系统管理员权限，你需要成为msdb数据库DatabaseMailUserRole的一员。

下面的脚本建立一些我在整个实例中都要用到的变量。注意：整个脚本将在msdb数据库中运行，Database Mail对象就保存在其中。

USE msdb

GO

DECLARE @ProfileName VARCHAR(255)

DECLARE @AccountName VARCHAR(255)

DECLARE @SMTPAddress VARCHAR(255)

DECLARE @EmailAddressVARCHAR(128)

DECLARE @DisplayUser VARCHAR(128)

这里我建立了ProfileName、AccountName、STMP服务器名称以及显示在电子邮件From（邮件来自）框中的地址。

SET @ProfileName = 'DBMailProfile';

SET @AccountName = 'DBMailAccount';

SET @SMTPAddress = 'mail.yoursmtpserver.com';

SET @EmailAddress = 'DBMail@yoursmtpserver.com';

SET @DisplayUser = 'The Mail Man';

列表A中的脚本完成一些清理工作，以便如果我再次运行脚本，就不必担心出现错误。

下面的脚本给系统增加账户（Account）、用户资料（Profile）和账户-用户资料（Account-Profile）关系。

EXECUTE msdb.dbo.sysmail_add_account_sp

@account_name = @AccountName,

@email_address = @EmailAddress,

@display_name = @DisplayUser,

@mailserver_name = @SMTPAddress

EXECUTE msdb.dbo.sysmail_add_profile_sp

@profile_name = @ProfileName

EXECUTE msdb.dbo.sysmail_add_profileaccount_sp

@profile_name = @ProfileName,

@account_name = @AccountName,

@sequence_number = 1 ;

现在一切都已经准备妥当，我将发送一封测试电子邮件。

EXEC msdb.dbo.sp_send_dbmail

@recipients=N'chapman.tim@gmail.com',

@body= 'Test Email Body',

@subject = 'Test Email Subject',

@profile_name = @ProfileName

要检查消息是否发送成功，我可以对sysmail_allitems系统视图执行一次查询。

SELECT * FROM sysmail_allitems

后续讨论

在下一篇文章中，我将为你介绍在SQL Server 2005中使用Database Mail发送电子邮件的各种选项。

Tim Chapman是肯塔基州路易维尔市一家银行的SQL Server数据库管理员，他有超过7年的IT行业经验。他还通过了微软SQL Server 2000和SQL Server 2005的认证。

责任编辑：张琎

查看本文国际来源

IF EXISTS

(

SELECT * FROM msdb.dbo.sysmail_profileaccount pa
      JOIN msdb.dbo.sysmail_profile p ON pa.profile_id = p.profile_id
      JOIN msdb.dbo.sysmail_account a ON pa.account_id = a.account_id

WHERE
      p.name = @ProfileName AND
      a.name = @AccountName
)

BEGIN
      PRINT 'Deleting Profile Account'
      EXECUTE sysmail_delete_profileaccount_sp
      @profile_name = @ProfileName,
      @account_name = @AccountName

END



IF EXISTS

(

SELECT * FROM msdb.dbo.sysmail_profile p 

WHERE p.name = @ProfileName

)

BEGIN
      PRINT 'Deleting Profile.'
      EXECUTE sysmail_delete_profile_sp
      @profile_name = @ProfileName

END



IF EXISTS

(

SELECT * FROM msdb.dbo.sysmail_account a

WHERE a.name = @AccountName

)

BEGIN
      PRINT 'Deleting Account.'
      EXECUTE sysmail_delete_account_sp
      @account_name = @AccountName

END