当对数据库中的数据进行读操作或修改时，数据库引擎使用专门的控制类型来保持数据库的完整性，称为锁机制。锁机制通过确保包含在一个事务中的数据库记录在该事务提交之前不能被其它事务修改来保证数据库的一致性。

在设计数据库应用时，你应该记住各种不同类型的锁及事务发生的不同隔离级别。通常情况下，SQL Server默认方式能够很好地完成你要使用的功能，不过，有些时候利用SQL语句在数据表上手工添加关于锁是如何应用的提示信息将是十分有用的。

本文主要介绍了两种数据表提示：NOLOCK和READPAST。我们将建立一个数据表用作例子中的查询数据表。执行列表A中的脚本建立一个SalesHistory数据表并添加一些数据。

NOLOCK

该数据表提示，也称为READUNCOMMITTED，只能用于SELECT语句。NOLOCK表明没有对数据表添加共享锁以阻止其它事务对数据表数据的修改。

该语句的好处是它可以使数据库引擎不用在处理查询中的上锁问题，可以提高并发性并改善数据库性能，因为数据库引擎不用在维护共享锁的使用问题。存在的问题是因为该语句不能处理要读取的数据表的所有锁，所以一些“脏数据”或未被提交的数据潜在的可能被读取。

如果某个事务被滚回，那么应用了NOLOCK连接的数据读取操作将可以读取未提交的数据。这种类型的读取导致处理的不一致性会带来很多问题。这是你使用NOLOCK时应该了解的技巧。

作为一个负面影响，NOLOCK查询还可能带来读取“幻影”数据或读取在一个数据库读取事务中可以获得的但在另一个事务中可能被滚回的数据的风险。（我将在本系列文章的第二部分对这个负面影响进行详细说明。）

下面的例子展示了NOLOCK如何工作以及脏数据读取是如何产生的。在下面的脚本中，我用一个事务在SalesHistory数据表中插入一条记录。

BEGIN TRANSACTION
INSERT INTO SalesHistory
(Product, SaleDate, SalePrice)
VALUES
('PoolTable', GETDATE(), 500)

这个事务仍旧是开放的，这意味着仍可以对插入数据表的记录上锁以阻止其它操作。在一个新的查询窗口中，运行下面的脚本，该脚本使用NOLOCK数据表提示返回SalesHistory数据表中的记录数。

SELECT COUNT(*) FROM SalesHistory WITH(NOLOCK)

返回记录数值为301。因为对SalesHistory数据表插入记录的事务还没有提交，所以我们可以撤销它。我通过使用下面的语句将事务滚回：

ROLLBACK TRANSACTION

该语句从SalesHistory数据表中删除前面插入的记录。现在我们运行前面运行的同样的SELECT语句。

SELECT COUNT(*) FROM SalesHistory WITH(NOLOCK)

这次返回记录数的值为300。我第一次查询读记录的事务还没有提交，这就是一个脏数据读取。 

READPAST

这是一个比NOLOCK较少使用的数据表提示。这个提示指明数据库引擎返回结果时忽略加锁的行或数据页。

这个数据表提示的优点和NOLOCK一样，在处理查询时不会发生阻塞。此外，读脏数据并不会出现在READPASTA中，因为不会返回锁定的记录。这个语句的缺点是，因为不返回锁定的记录，所以很难确定结果集或修改语句是否包含所有必须的记录。在你的应用中可能需要添加一些逻辑来确保最终包含所有必须的记录。

READPAST数据表提示的例子和NOLOCK的例子类似。我将使用一个事务来更新SalesHistory数据表中的一个记录。

BEGIN TRANSACTION
UPDATE TOP(1) SalesHistory
SET SalePrice = SalePrice + 1

因为我没有提交或回滚这个事务，所以添加在更新记录上的锁仍旧有效。在一个新的查询编辑窗口中，运行下面的脚本，该脚本对SalesHistory数据表使用READPAST统计表中的记录数。

SELECT COUNT(*)
FROM SalesHistory WITH(READPAST)

最初SalesHistory数据表中包含300条记录，UPDATE语句正锁定表中一条记录，所以上面使用READPAST的脚本返回结果为299条记录，这说明我要更新的记录被锁定，所以被REASPAST提示忽略。

Tim chapman是位于路易斯维尔一家银行工作的SQL Server数据库管理员，有7年多的IT经验，同时，他还获得了微软SQL Server 2000 和SQL Server 2005认证。

责任编辑：德东

查看本文国际来源

IF OBJECT_ID('SalesHistory')>0      

DROP TABLE SalesHistory;

GO

CREATE TABLE [dbo].[SalesHistory]

(      

      [SaleID] [int] IDENTITY(1,1) NOT NULL PRIMARY KEY,      

      [Product] [char](150) NULL,      

            [SaleDate] [datetime] NULL,      

            [SalePrice] [money] NULL

)

GO

DECLARE @i SMALLINT

SET @i = 1

WHILE (@i <=100)

BEGIN                  

      INSERT INTO SalesHistory               

      (Product, SaleDate, SalePrice)                  

      VALUES      

      ('Computer', DATEADD(mm, @i, '3/11/1919'), DATEPART(ms, GETDATE()) + (@i + 57))      

      INSERT INTO SalesHistory                

      (Product, SaleDate, SalePrice)      

      VALUES             

      ('BigScreen', DATEADD(mm, @i, '3/11/1927'), DATEPART(ms, GETDATE()) + (@i + 13))                  

      INSERT INTO SalesHistory                  

      (Product, SaleDate, SalePrice)          

      VALUES            

      ('PoolTable', DATEADD(mm, @i, '3/11/1908'), DATEPART(ms, GETDATE()) + (@i + 29))                  

      SET @i = @i + 1

END

GO